Source   Edit

This package can be used for simple tasks that need to run on an interval or at a certain time.

It has both an async and non-async api (They are similar, only difference being in creation of scheduler)

Making tasks

The main procs for creating tasks are

• every When you want a task to run on an interval (First run is when start() is called)
• at When you want the task to run once at a certain date (Runs once)
• wait When you want to wait a certain amount of time and then run the task (Runs once)

Example: cmd: -r:off

import taskman
let tasks = newAsyncScheduler() # or newScheduler if you don't want to use async

tasks.every(5.minutes) do () {.async.}:
  echo "This will run every 5 minutes"

tasks.at("2077-01-1".parse("yyyy-mm-dd")) do () {.async.}:
  echo "This will run on the 1st of janurary in 2077"

tasks.wait(10.hours) do () {.async.}:
  echo "This will run after 10 hours"

# Block the thread and run tasks when needed
# asyncCheck could be used instead e.g. so you can have a web server running also
# You could also put it onto another thread
waitFor tasks.start()

By default the scheduler will end when all tasks are finished (i.e. every at and wait task has completed). It also will run tasks late if they are added while the scheduler is sleeping while waiting for a tasks start time. To change this behaviour you can add a periodicCheck parameter to the start function which will make the scheduler check every periodicCheck seconds for which task it should be waiting on

Example: cmd: -r:off

import taskman
let tasks = newAsyncScheduler()

proc main() {.async.} =
  tasks.every(10.minutes) do () {.async.}:
    echo "10 minutes has passed"
  asyncCheck tasks.start(100) # The scheduler will check every 100 milliseconds for new tasks

  # If we didn't have the periodicCheck passed before then this task would only run after
  # the 10 minutes task before has ran
  tasks.wait(5.seconds) do () {.async.}:
    echo "5 seconds has passed"

waitFor main()

Deleting Tasks

Tasks can be directly removed using del

Example:

import taskman
let 
  tasks = newScheduler()
  taskA = newTask[TaskHandler](5.seconds, proc () = echo "hello")

tasks &= taskA
tasks.every(1.days, (proc () = echo "A new dawn appears"), name = "newDay")
assert tasks.len == 2

# Tasks can be deleted either with their name or using the original task obj
tasks.del taskA
tasks.del "newDay"
assert tasks.len == 0

If inside a task, then removeTask can be used to remove the current task (This is just a helper to raise RemoveTaskException). onlyRun is another helper which calls removeTask after a task has run a certain number of times

Example:

import taskman
let tasks = newScheduler()

tasks.every(1.milliseconds) do ():
  if true:
    echo "I don't want to run anymore"
    removeTask() #

tasks.every(1.milliseconds) do ():
  if not false:
    raise (ref RemoveTaskException)()

var i = 1
tasks.every(1.nanoseconds) do ():
  onlyRun(3)
  # This task will only run three times (Terminates at the end of the 3 run)
  echo i
  inc i

assert tasks.len == 3
tasks.start() # Tasks will be deleted when ran in this scenario
assert tasks.len == 0

Cron

For more advanced intervals you can instead use cron timers

Example:

import taskman
let tasks = newScheduler()

# Just like * * * * *
tasks.every(cron(x, x, x, x, x)) do ():
  echo "Minute has passed"

tasks.every(cron(5, 10, x, x, x)) do ():
  echo "It is the 5th minute of the 10th hour"

See the cron module for more info on the syntax